SaveAs Method, FormField class

Description

Lets you save this form field under specified file name.

Syntax

FormField.SaveAs (FileName as String)

Where	Type	Optional	Default	Description
FileName	String			Full path and file name.

Examples

Upload - Save form files with special name.

Upload - Save extra upload info to a database

<%
'Sample file Field-SaveAs.asp 
'Store extra upload info to a database
' and file contents to the disk

'Create upload form
Dim Form: Set Form = Server.CreateObject("ScriptUtils.ASPForm")

'was the Form successfully received?
If Form.State = 0 Then

  'Create destination path+filename for the source file.
  Dim DestinationPath, DestinationFileName
  DestinationPath = Server.MapPath(".") & "\"
  DestinationFileName = "~upload-" & Form("SourceFile").FileName


  'Open recordset to store uploaded data
  Dim RS: Set RS = OpenUploadRS

  'Store extra info about upload to database
  RS.AddNew
   RS("UploadDT") = Now()
   RS("Description") = Form.Texts("Description")
   RS("SourceFileName") = DestinationFileName
   '...
  RS.Update

  'Save file to the destination
  Form("SourceFile").SaveAs DestinationPath & DestinationFileName
  '

  Response.Write "<br>Source file names:"
  Dim Field: For Each Field In Form
    Response.Write "<br> " & Field.FileName
  Next
End If'Form.State = 0 then

Function OpenUploadRS()
  Dim RS  : Set RS = CreateObject("ADODB.Recordset")

  'Open dynamic recordset, table Upload
  RS.Open "Upload", GetConnection, 2, 2
  
  Set OpenUploadRS = RS
End Function 

Function GetConnection()
  Dim Conn: Set Conn = CreateObject("ADODB.Connection")
  Conn.Provider = "Microsoft.Jet.OLEDB.4.0"
  Conn.open "Data Source=" & Server.MapPath("upload.mdb") 
	Set GetConnection = Conn
End Function



%>  
<br>sample For <A Href=http://www.motobit.com>HugeASP upload</A>
<br>Store extra upload info To a database
<br> And file contents To the disk
<form name="file_upload" method="POST" ENCTYPE="multipart/form-data">
File1:<input Name=SourceFile Type=File><br>
Description:<input Name=Description><br>
<input Name=SubmitButton Value="Submit >>" Type=Submit><br>
</Form>

Other links for SaveAs

Methods of FormField class

ContentCharSet, Save, SaveAs

Properties of FormField class

ByteArray, ContentDisposition, ContentTransferEncoding, ContentType, FileExt, FileName, FilePath, Header, Headers, HexString, CharSet, Index, InProgress, IsFile, Length, Name, RAWHeader, SourceLength, String, Value

ScriptUtils.FormField

One form field. Member of FormFields collection.

ScriptUtils

Easy to use, hi-performance ASP file upload component with progress bar indicator. Let's you upload multiple files with size up to 2GB to a disk or database along with another form fields. Works with large posts, any character set (including unicode utf-8). Contains one-click multiple files/folders download with on-the-fly compression (Using BinaryWrite/BinaryRead).

      Hi-performance text file logging for ASP/VBScript/VBA applications. Lets you create daily/weekly/monthly log files with variable number of logged values and extra timing and performance info.
       Lets you work with safearray binary data in VBS/JS. It also enables conversion between binary and String data using several code pages. ZLib compress and uncompress functions. Lets you transfer files using compressed stream from a client to server using IE.
      This library also enables calling of some Kernel and Advapi functions (performance, timing, sleep, configuration ...) and enables native work with INI files.